Maršál-vægtkurver i MS Excel regneark

Maršál referencekurve

Visning af vægtreference og beregning af vægtafvigelse for konkrete fødselsvægte kan naturligvis også lade sig gøre i et MS Excel regneark.
Omsat til Excel ser kurveformlerne for Maršál's vægtreferencer således ud:

Vægt-reference(g) for Piger:
Excel:

=-2,761948*10^-6*A3^4 +1,744841*10^-3*A3^3 -2,893626*10^-1*A3^2 +1,891197*10^1*A3 -4,135122*10^2
hvor kolonne A angiver GA-alder i dage.

Vægt-reference(g) for Drenge:
Excel:

=-1,907345*10^-6*A3^4 +1,140644*10^-3*A3^3 -1,336265*10^-1*A3^2 +1,976961*10^0*A3 +2,410053*10^2
hvor kolonne A angiver GA-alder i dage.

De viste formler for middelvægt i relation til gestationsalder er implementeret således, at arkets to øverste rækker er tiltænkt overskrifter, og den valgte af de viste formler er lagt i f.eks. celle C3 med reference til GA(dage) i celle A3.

Den automatiske parallelle visning af GA som uu+d nås med formlen:
=(A3-MOD(A3;7))/7&"+"&MOD(A3;7)

Evaluering af observerede data med reference til Maršál

Excel kan være praktisk til (mindre) ad hoc evalueringer af observerede data. Anvendelse af Excel til datalagring må imidlertid frarådes, da lagring i Excel hvor arket indeholder patientidentificerbare oplysninger, ikke lever op til lov om datalagring af personhenførbare oplysninger.

For beregning af vægtafvigelse på observerede data i forhold til Maršál's kurve kan man i Excel lægge de observerede GA hele uger i kolonne B, GA +dage i kolonne C, GA uger+dage omregnet til dage i kolonne D, barnets køn ("p" eller "d") i kolonne E og barnets fødselsvægt i kolonne F. En adaptiv vægtreference (tilpasser sig hhv. piger og drenge) kunne se sådan ud med udgangspunkt i at data og formel i dette tilfælde ligger i række 5 i Excel-arket:
=HVIS(D5>=154;HVIS(D5<301;HVIS(E5="p";-2,761948*10^-6*D5^4 +1,744841*10^-3*D5^3 -2,893626*10^-1*D5^2 +1,891197*10^1*D5 -4,135122*10^2
;HVIS(E5="d";-1,907345*10^-6*D5^4 +1,140644*10^-3*D5^3 -1,336265*10^-1*D5^2 +1,976961*10^0*D5 +2,410053*10^2;""));"");"")

hvor udtrykket i een og samme kolonne viser vægtreference hvadenten pige eller dreng, idet udtrykket dynamisk afspejler markeringen for hhv. pige eller dreng i kolonne E. I det viste udtryk er gestationsalder-betingelsen extrapoleret ned til GA 22+0 (154 dage). IF/HVIS- betingelserne sørger desuden for at vise tom resultatcelle, hvis GA eller køn mangles oplyst.

Hvis ovennævte vægtreference udtryk lægges i kolonne G, vil man i kolonne H for den procentuelle vægtdeviation kunne lægge udtrykket:
=HVIS(G5<>"";HVIS(F5>0;HVIS(F5<9999;HVIS(E5="p";(F5-G5)/G5*100;HVIS(E5="d";(F5-G5)/G5*100;""));"");"");"")
og i kolonne I lægge udtrykket for vægtdeviation udtrykt i SD (forudsat -1SD = mean - 12%):
=HVIS(H5<>"";H5/12;"")
og i kolonne J udtrykket for LGA/AGA/SGA forudsat at SGA defineres som -2SD:
=HVIS(H5<>"";HVIS(H5>24;"LGA";HVIS(H5<-24;"SGA";"AGA"));"")
Ovenstående implementering kunne se således ud med beregnede felter markeret med blåt:

P.S.: Når f.eks. celle I5 viser afvigelse -2,00 SD (og ikke -1,99 SD) skyldes det, at vægtreferencen i kolonne G viser værdier afrundet til hele gram af underliggende decimaltal.
Vægtreferencen i f.eks. G5 er således underliggende 2875,3828..g, der er den beregningsmæssigt anvendte værdi, og den afledte afvigelse -1,995 SD afrundet til -2,00 SD.
Række 5-6 viser hvordan vægtreferencen adapterer til pige vs. dreng for samme GA og samme FV.
Række 7 viser vægtreference og vægtafvigelses-beregning for ekstrapoleret Maršál-reference (GA<25).

Ulemper ved anvendelse af Excel: